Table of Contents
Methods
method subbuf-rw
routine subbuf-rw
method reallocate
method list
method push
method pop
method append
method prepend
method shift
method unshift
method splice
Methods on buf8 only (6.d, 2018.12 and later)
method write-uint8
method write-int8
method write-uint16
method write-int16
method write-uint32
method write-int32
method write-uint64
method write-int64
method write-uint128
method write-int128
method write-num32
method write-num64
Methods on buf8 only (6.d, 2019.03 and later)
method write-ubits
method write-bits
Methods on buf8 only (6.d, 2019.10 and later)
method write-uint8
method write-int8
method write-uint16
method write-int16
method write-uint32
method write-int32
method write-uint64
method write-int64
method write-uint128
method write-int128
method write-num32
method write-num64
method write-ubits
method write-bits

Index

Types

buf32

buf64

buf8

role Buf

Mutable buffer for binary data

role Buf[::T = uint8] does Blob[T] is repr('VMArray') is array_type(T){ ... }

A Buf does the role of a mutable sequence of (usually unsigned) integers.

my $b = Buf.new(1, 2, 3);
$b[1] = 42;

However, it's a parameterized type, and you can instantiate with several integer types:

my $b = Buf[int32].new(3, -3, 0xff32, -44);
say $b; # OUTPUT: «Buf[int32]:0x<03 -3 FF32 -2C>»

By default, Buf uses 8-bit unsigned integers, that is, it is equivalent to Buf[uint8]. Some other types of Bufs which are used often get their own class name.

buf8	Buf[uint8]
buf16	Buf[uint16]
buf32	Buf[uint32]
buf64	Buf[uint64]

You can use these in pretty much the same way you would with Buf:

my $buf = buf8.new(3, 6, 254);
say $buf; # OUTPUT: «Buf[uint8]:0x<03 06 fe>␤»

Plus there are some object methods, like encode that might return a buf8 in some cases where it is the best representation for a particular encoding.

Methods

method subbuf-rw

method subbuf-rw($from = 0, $elems = self.elems - $from) is rw

A mutable version of subbuf that returns a Proxy functioning as a writable reference to a part of a buffer. Its first argument, $from specifies the index in the buffer from which a substitution should occur, and its last argument, $elems specifies how many elements are to be replaced.

For example, to replace one element at index 3 with two elements, 100 and 101:

my Buf $b .= new(0..5);
$b.subbuf-rw(3,1) = Buf.new(100, 101);
say $b.raku;   # OUTPUT: «Buf.new(0,1,2,100,101,4,5)␤»

In the case the $elems argument is not specified, the substitution happens at the specified index $from removing all trailing elements:

my Buf $b .= new(0..5);
$b.subbuf-rw(3) = Buf.new(200);
say $b.raku;   # OUTPUT: «Buf.new(0,1,2,200)␤»

In the case the $from argument is not specified, the substitution happens from the very beginning of the buffer:

my Buf $b .= new(0..5);
$b.subbuf-rw = Buf.new(123, 123);
say $b.raku;   # OUTPUT: «Buf.new(123, 123)␤»

routine subbuf-rw

multi sub subbuf-rw(Buf:D \b) is rw
multi sub subbuf-rw(Buf:D \b, Int() $from) is rw
multi sub subbuf-rw(Buf:D \b, $from, $elems) is rw

Returns a writable reference to a part of a buffer. Invokes the subbuf-rw method on the specified Buf:

my Buf $b .= new(1,2,3);
subbuf-rw($b,2,1) = Buf.new(42);
say $b.raku;   # OUTPUT: «Buf.new(1,2,42)␤»

method reallocate

method reallocate(Buf:D: Int:D $elems)

Change the number of elements of the Buf, returning the changed Buf. The size of Buf will be adapted depending on the number of $elems specified: if it is smaller than the actual size of the Buf the resulting Buf will be shrunk down, otherwise it will be enlarged to fit the number of $elems. In the case the Buf is enlarged, newly created items will be assigned a Virtual Machine specific null value, therefore you should not rely upon their value since it could be inconsistent across different virtual machines.

my Buf $b .= new(^10);
$b.reallocate(5);
say $b.raku;  # OUTPUT: «Buf.new(0,1,2,3,4)␤» 
 
$b = Buf.new( 1..3 );
$b.reallocate( 10 );
$b.raku.say; # OUTPUT: «Buf.new(1,2,3,0,0,0,0,0,0,0)␤»

method list

multi method list(Buf:D:)

Returns a List of integers.

say Buf.new(122,105,112,205).list; # OUTPUT: «(122 105 112 205)␤»

method push

method push( $elems )

Adds elements at the end of the buffer

my @φ =  1,1, * + * … ∞;
my $bú = Buf.new( @φ[^5] );
$bú.push( @φ[5] );
say $bú.raku; # OUTPUT: «Buf.new(1,1,2,3,5,8)»

method pop

method pop()

Extracts the last element of the buffer

say $bú.pop(); # OUTPUT: «8» 
say $bú.raku; # OUTPUT: «Buf.new(1,1,2,3,5)»

method append

method append( $elems )

Appends at the end of the buffer

$bú.append( @φ[5..10] );
say $bú.raku; # OUTPUT: «Buf.new(1,1,2,3,5,8,13,21,34,55,89)»

method prepend

method prepend( $elems )

Adds elements at the beginning of the buffer

$bú.prepend( 0 );
say $bú.raku; # OUTPUT: «Buf.new(0,1,1,2,3,5,8,13,21,34,55,89)»

method shift

method shift()

Takes out the first element of the buffer

$bú.shift();
say $bú.raku; # OUTPUT: «Buf.new(1,1,2,3,5,8,13,21,34,55,89)»

method unshift

method unshift()

Adds elements at the beginning of the buffer

$bú.unshift( 0 );
say $bú.raku; # OUTPUT: «Buf.new(0,1,1,2,3,5,8,13,21,34,55,89)»

method splice

method splice( Buf:D: $start = 0, $elems?, *@replacement --> Buf)

Substitutes elements of the buffer by other elements

$bú.splice:  0, 3, <3 2 1>;
say $bú.raku; # OUTPUT: «Buf.new(3,2,1,2,3,5,8,13,21,34,55,89)»

Methods on buf8 only (6.d, 2018.12 and later)

These methods are available on the buf8 type only. They allow low level access to writing bytes to the underlying data and in different ways with regards to type (integer or floating point (num)), size (8, 16, 32, 64 or 128 bits), signed or unsigned (for integer values) and endianness (native, little and big endianness). These methods always return Nil.

Endianness must be indicated by using values of the Endian enum as the third parameter to these methods. If no endianness is specified, NativeEndian will be assumed. Other values are LittleEndian and BigEndian.

The buffer will be automatically resized to support any bytes being written if it is not large enough yet.

method write-uint8

method write-uint8(buf8:D: uint $pos, uint8 $value, $endian = NativeEndian --> Nil)

Writes an unsigned 8-bit integer value at the given position. The $endian parameter has no meaning, but is available for consistency.

method write-int8

method write-int8(buf8:D: uint $pos, int8 $value, $endian = NativeEndian --> Nil)

Writes a signed 8-bit integer value at the given position. The $endian parameter has no meaning, but is available for consistency.

method write-uint16

method write-uint16(buf8:D: uint $pos, uint16 $value, $endian = NativeEndian --> Nil)

Writes an unsigned 16-bit integer value at the given position with the given endianness.

method write-int16

method write-int16(buf8:D: uint $pos, int16 $value, $endian = NativeEndian --> Nil)

Writes a signed 16-bit integer value at the given position with the given endianness.

method write-uint32

method write-uint32(buf8:D: uint $pos, uint32 $value, $endian = NativeEndian --> Nil)

Writes an unsigned 32-bit integer value at the given position with the given endianness.

method write-int32

method write-int32(buf8:D: uint $pos, int32 $value, $endian = NativeEndian --> Nil)

Writes a signed 32-bit integer value at the given position with the given endianness.

method write-uint64

method write-uint64(buf8:D: uint $pos, uint64 $value, $endian = NativeEndian --> Nil)

Writes an unsigned 64-bit integer value at the given position with the given endianness.

method write-int64

method write-int64(buf8:D: uint $pos, Int:D $value, $endian = NativeEndian --> Nil)

Writes a signed 64-bit integer value at the given position with the given endianness.

method write-uint128

method write-uint128(buf8:D: uint $pos, UInt:D $value, $endian = NativeEndian --> Nil)

Writes an unsigned 128-bit integer value at the given position with the given endianness.

method write-int128

method write-int128(buf8:D: uint $pos, Int:D $value, $endian = NativeEndian --> Nil)

Writes a signed 128-bit integer value at the given position with the given endianness.

method write-num32

method write-num32(buf8:D: uint $pos, num32 $value, $endian = NativeEndian --> Nil)

Writes a native num32 IEEE floating point value at the given position with the given endianness.

method write-num64

method write-num64(buf8:D: uint $pos, num64 $value, $endian = NativeEndian --> Nil)

Writes a native num64 IEEE floating point value at the given position with the given endianness.

Methods on buf8 only (6.d, 2019.03 and later)

method write-ubits

method write-ubits(buf8:D: uint $pos, uint $bits, UInt:D $value --> Nil)

Writes an unsigned integer value to the bits from the given bit offset and given number of bits. The endianness of the bits is assumed to be BigEndian. Always returns Nil.

method write-bits

method write-bits(buf8:D: uint $pos, uint $bits, Int:D $value --> Nil)

Writes a signed integer value for the bits from the given bit offset and given number of bits. The endianness of the bits is assumed to be BigEndian. Always returns Nil.

Methods on buf8 only (6.d, 2019.10 and later)

These methods can also be called on the buf8 type object, in which case a new buf8 object will be returned. Otherwise, the invocant will be returned to allow for easier chaining of operations on the buf8 object. The buffer will be automatically resized to support any bytes being written if it is not large enough yet.